Bend

Keyword	Abbreviation	Token (hex)	Version(s)	Classification
BEND	BE{Shift+N}	FE 19	7.0	Command, Preposition, and Statement

Syntax

IF condition { GOTO lineNumTrue | THEN [ lineNumTrue | BEGIN ] } [ statementT ] [ : statementT ] ...

[ statementT : ] ... BEND [ junk1 ] [ : ELSE [ lineNumFalse | BEGIN ] [ statementF ] [ : statementF ] ...

[ statementF : ] ... BEND [ junk2 ] ]

Parameters	Type	Legal Value(s)	Default Value	Note(s)
condition	Boolean	all numeric
lineNumTrue	Unsigned integer	0 ~ 63999		Must be a literal number Branched to when condition is true (not 0)
statementT	Command or Statement	all*		Must be valid in current direct/RUN mode Executed when condition is true (not 0)
junk1	Literal character(s)	any but colon (:)		ignored; similar to DATA
lineNumFalse	Unsigned integer	0 ~ 63999		Only valid in v3.5, 4.7, and 7.0 Must be a literal number. Branched to when condition is false (0)
statementF	Command or Statement	all*		Only valid in v3.5, 4.7, and 7.0 Must be valid in current direct/RUN mode Executed when condition is false (0)
junk2	Literal character(s)	all		ignored; just like REM

Purpose

Program formatting. Allow conditional clause(s) to span multiple program lines.

Remarks

Although the syntax shown above is rather complex, BEND is very simple. It should appear at the end of any conditional clause (the statment(s) after THEN or ELSE) which started with the BEGIN keyword. So it is very similar to RETURN which ends a subroutine (but the stack isn't normally used). The BEGIN/BEND surround the clause(s) to allow conditional statements to span multiple lines. Without BEGIN/BEND, the entire IF/THEN/ELSE construct must fit on a single line.

In BASIC versions prior to 7.0 (i.e., with no BEGIN/BEND), there were two (or three) alternatives when a clause had too many statements to fit on a single line:

use GOTO statements to branch over the "wrong" case,
or use GOSUB to call the block of statments,
or a combination of the two.

Failure to include BEND will silently succeed when IF happens to be processing the clause that includes a lonely BEGIN; but when IF processes the opposite case, you will generate a BEND NOT FOUND ERROR. Err, kind of hard to explain in words, so see the examples below!

* The selected command/statement must be valid for the current Interpreter mode (Direct Mode or Run Mode, per the current state of the BASIC Interpreter).

The BEND at the end of the THEN clause (i.e., before an ELSE, if any) may be followed by any junk characters except a colon (:). This is because BEND is implemented using the code of DATA (although no values following BEND can be READ), in otherwords, BEND acts like REM, but another statment may appear on the line (REM does not allow that). Anyway, at the end of a THEN clause, BASIC will check what (if anything) follows the colon after BEND (it is looking for ELSE).

The BEND at the end of an ELSE clause is effectively just like REM because BASIC will not search for another colon (:), but in general simply continue with the next line in the program. Thus junk2 may be any sequence of characters, in general. Note however that with nested IF/THEN/ELSE, BASIC may still be searching for a BEND after this one is found. In which case junk2 should not include the keywords BEGIN/BEND.

BEGIN/BEND allows real nesting of IF/THEN/ELSE statments (it is broken otherwise, see ELSE). Beware that BASIC does not impose any limits on the depth of nesting which can cause the system to mysteriously crash. In detail, when BEGIN is found while BEND is being sought, BASIC will recursively call "find BEND" which uses 2 bytes of the CPU stack but no test is ever made to see if space is available on the CPU stack.

** Using BEND like a command or statement (instead of an IF/THEN/ELSE preposition) will act like REM. This serves little purpose other than making lame jokes or code obfusication.

Example 1:

NEW

READY.
10 X=1 : IF X=1 THEN BEGIN
20 : PRINT "TRUE" : X = 2 : BEND : ELSE PRINT "FALSE" : X = 0
30 PRINT X
RUN
TRUE 2

READY.
NEW : REM demonstrate 'safe' omission of BEND (line 20)

READY.
10 X=1 : IF X=1 THEN BEGIN
20 : PRINT "TRUE" : X = 2 : ELSE PRINT "FALSE" : X = 0
30 PRINT X
RUN
TRUE 2

READY.
NEW : REM demonstrate 'bad' omission of BEND (line 20)

READY.
10 X=99 : IF X=1 THEN BEGIN
20 : PRINT "TRUE" : X = 2 : ELSE PRINT "FALSE" : X = 0
30 PRINT X
RUN
?BEND NOT FOUND ERROR IN 30

READY.
REM demonstrate BEND as REM

READY.
BENDER IS A 6502-BASED ANDROID Y3K

READY.

Example 2 is for BASIC v1.0 and v2.x which lack ELSE and BEING/BEND:

NEW

READY.
10 X=1 : IF X=1 THEN PRINT "TRUE" : X=2 : GOTO 30 :REM THEN clause + GOTO to skip ELSE clause
20 PRINT "FALSE" : X = 0 : REM the ELSE clause
30 PRINT X
RUN
TRUE 2

READY.
NEW

READY.
10 X=1 : IF X=1 THEN GOSUB 100 : GOTO 30 :REM call THEN clause + Skip ELSE clause
20 PRINT "FALSE" : X = 0 : REM the ELSE clause
30 PRINT X : END
100 PRINT "TRUE" : X=2 : RETURN
RUN
TRUE 2

READY.

See Also

BEGIN, ELSE, GOTO, IF, THEN

Compare With

RETURN